Add integration tests for cat

Author: afarber

test/cat/CMakeLists.txt

@@ -14,6 +14,18 @@ function(check_convert _name _input _output _format)
     check_output(cat ${_name} "cat --no-progress --generator=test cat/${_input} -f ${_format}" "cat/${_output}")
 endfunction()
 
+function(check_warning _name _input _format _expected_stderr)
+    set(_cmd "$<TARGET_FILE:osmium> cat --no-progress --generator=test cat/${_input} -f ${_format} -o /tmp/test-warning-output.osm --overwrite")
+    add_test(
+        NAME "cat-${_name}"
+        COMMAND ${CMAKE_COMMAND}
+        -D cmd:FILEPATH=${_cmd}
+        -D dir:PATH=${PROJECT_SOURCE_DIR}/test
+        -D expected_stderr:STRING=${_expected_stderr}
+        -P ${CMAKE_SOURCE_DIR}/test/cat/run_test_check_stderr.cmake
+    )
+endfunction()
+
 
 #-----------------------------------------------------------------------------
 
@@ -26,5 +38,9 @@ check_convert(bzip2 input1.osm.bz2 output1.osm.opl opl)
 check_convert(pbf input1.osm.pbf output1.osm.opl opl)
 check_convert(opl output1.osm.opl output1.osm.opl opl)
 
+check_warning(warning-xml input-with-locations.osm xml "Warning! Input file contains locations on ways that will be lost in output.")
+check_warning(warning-pbf input-with-locations.osm pbf "Warning! Input file contains locations on ways that will be lost in output.")
+check_warning(warning-opl input-with-locations.osm opl "Warning! Input file contains locations on ways that will be lost in output.")
+
 
 #-----------------------------------------------------------------------------

test/cat/run_test_check_stderr.cmake

@@ -0,0 +1,38 @@
+#
+# Runs a test command and checks that stderr contains expected warning message.
+# Used for testing warning functionality.
+#
+
+if(NOT cmd)
+    message(FATAL_ERROR "Variable 'cmd' not defined")
+endif()
+
+if(NOT dir)
+    message(FATAL_ERROR "Variable 'dir' not defined")
+endif()
+
+if(NOT expected_stderr)
+    message(FATAL_ERROR "Variable 'expected_stderr' not defined")
+endif()
+
+message("Executing: ${cmd}")
+separate_arguments(cmd)
+
+execute_process(
+    COMMAND ${cmd}
+    WORKING_DIRECTORY ${dir}
+    RESULT_VARIABLE _return_code
+    OUTPUT_VARIABLE _stdout
+    ERROR_VARIABLE _stderr
+)
+
+if(NOT _return_code EQUAL 0)
+    message(FATAL_ERROR "Command failed with return code ${_return_code}")
+endif()
+
+string(FIND "${_stderr}" "${expected_stderr}" _found_pos)
+if(_found_pos EQUAL -1)
+    message(FATAL_ERROR "Expected stderr message '${expected_stderr}' not found in stderr output: '${_stderr}'")
+endif()
+
+message(STATUS "Test passed: Found expected stderr message")