Merge pull request #102 from open-api-spex/lookup-operation-by-phoenix-controller-action

Add operation lookup by phoenix {controller, action}

Author: mbuhot

lib/open_api_spex/plug/cache.ex

@@ -0,0 +1,50 @@
+defmodule OpenApiSpex.Plug.Cache do
+  @moduledoc false
+
+  @callback get(module) :: {OpenApiSpex.OpenApi.t(), map} | nil
+  @callback put(module, {OpenApiSpex.OpenApi.t(), map}) :: :ok
+
+  @spec adapter() :: OpenApiSpex.Plug.AppEnvCache | OpenApiSpex.Plug.PersistentTermCache
+  def adapter do
+    if function_exported?(:persistent_term, :info, 0) do
+      OpenApiSpex.Plug.PersistentTermCache
+    else
+      OpenApiSpex.Plug.AppEnvCache
+    end
+  end
+end
+
+defmodule OpenApiSpex.Plug.AppEnvCache do
+  @moduledoc false
+  @behaviour OpenApiSpex.Plug.Cache
+
+  @impl OpenApiSpex.Plug.Cache
+  def get(spec_module) do
+    Application.get_env(:open_api_spex, spec_module)
+  end
+
+  @impl OpenApiSpex.Plug.Cache
+  def put(spec_module, spec) do
+    :ok = Application.put_env(:open_api_spex, spec_module, spec)
+  end
+end
+
+if function_exported?(:persistent_term, :info, 0) do
+  defmodule OpenApiSpex.Plug.PersistentTermCache do
+    @moduledoc false
+    @behaviour OpenApiSpex.Plug.Cache
+
+    @impl OpenApiSpex.Plug.Cache
+    def get(spec_module) do
+      :persistent_term.get(spec_module)
+    rescue
+      ArgumentError ->
+        nil
+    end
+
+    @impl OpenApiSpex.Plug.Cache
+    def put(spec_module, spec) do
+      :ok = :persistent_term.put(spec_module, spec)
+    end
+  end
+end

lib/open_api_spex/plug/cast_and_validate.ex

@@ -80,14 +80,37 @@ defmodule OpenApiSpex.Plug.CastAndValidate do
 
   def call(
         conn = %{
-          private: %{phoenix_controller: controller, phoenix_action: action, open_api_spex: _pd}
+          private: %{
+            phoenix_controller: controller,
+            phoenix_action: action,
+            open_api_spex: private_data
+          }
         },
         opts
       ) do
-    operation_id = controller.open_api_operation(action).operationId
+    operation =
+      case private_data.operation_lookup[{controller, action}] do
+        nil ->
+          operationId = controller.open_api_operation(action).operationId
+          operation = private_data.operation_lookup[operationId]
 
-    if operation_id do
-      call(conn, Map.put(opts, :operation_id, operation_id))
+          operation_lookup =
+            private_data.operation_lookup
+            |> Map.put({controller, action}, operation)
+
+          OpenApiSpex.Plug.Cache.adapter().put(
+            private_data.spec_module,
+            {private_data.spec, operation_lookup}
+          )
+
+          operation
+
+        operation ->
+          operation
+      end
+
+    if operation.operationId do
+      call(conn, Map.put(opts, :operation_id, operation.operationId))
     else
       raise "operationId was not found in action API spec"
     end

lib/open_api_spex/plug/put_api_spec.ex

@@ -9,7 +9,7 @@ defmodule OpenApiSpex.Plug.PutApiSpec do
       plug OpenApiSpex.Plug.PutApiSpec, module: MyAppWeb.ApiSpec
   """
   @behaviour Plug
-  @before_compile __MODULE__.Cache
+  @cache OpenApiSpex.Plug.Cache.adapter()
 
   @impl Plug
   def init([module: _spec_module] = opts) do
@@ -19,12 +19,20 @@ defmodule OpenApiSpex.Plug.PutApiSpec do
   @impl Plug
   def call(conn, spec_module) do
     {spec, operation_lookup} =
-      fetch_spec(spec_module)
+      case @cache.get(spec_module) do
+        nil ->
+          spec = build_spec(spec_module)
+          @cache.put(spec_module, spec)
+          spec
+        spec ->
+          spec
+      end
 
     private_data =
       conn
       |> Map.get(:private)
       |> Map.get(:open_api_spex, %{})
+      |> Map.put(:spec_module, spec_module)
       |> Map.put(:spec, spec)
       |> Map.put(:operation_lookup, operation_lookup)
 
@@ -47,44 +55,4 @@ defmodule OpenApiSpex.Plug.PutApiSpec do
     |> Stream.map(fn operation -> {operation.operationId, operation} end)
     |> Enum.into(%{})
   end
-
-  defmodule Cache do
-    defmacro __before_compile__(_env) do
-      if function_exported?(:persistent_term, :info, 0) do
-        quote do
-          def fetch_spec(spec_module) do
-            try do
-              :persistent_term.get(spec_module)
-            rescue
-              ArgumentError ->
-                term_not_found()
-                spec = build_spec(spec_module)
-                :ok = :persistent_term.put(spec_module, spec)
-                spec
-            end
-          end
-
-          defp term_not_found do
-            if Application.get_env(:open_api_spex, :persistent_term_warn, false) do
-              IO.warn("Warning: the OpenApiSpec spec was deleted from persistent terms. This can cause serious issues.")
-            else
-              Application.put_env(:open_api_spex, :persistent_term, true)
-            end
-          end
-        end
-      else
-        quote do
-          def fetch_spec(spec_module) do
-            case Application.get_env(:open_api_spex, spec_module) do
-              nil ->
-                spec = build_spec(spec_module)
-                Application.put_env(:open_api_spex, spec_module, spec)
-                spec
-              spec -> spec
-            end
-          end
-        end
-      end
-    end
-  end
 end