npm: add module

Author: mirkolenz

modules/programs/npm.nix

@@ -0,0 +1,53 @@
+# https://github.com/NixOS/nixpkgs/blob/master/nixos/modules/programs/npm.nix
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+let
+  cfg = config.programs.npm;
+in
+{
+  meta.maintainers = with lib.maintainers; [ mirkolenz ];
+
+  options = {
+    programs.npm = {
+      enable = lib.mkEnableOption "{command}`npm` user config";
+
+      package = lib.mkPackageOption pkgs [ "nodePackages" "npm" ] {
+        example = "nodePackages_13_x.npm";
+        nullable = true;
+      };
+
+      npmrc = lib.mkOption {
+        type = lib.types.lines;
+        description = ''
+          The user-specific npm configuration.
+          See <https://docs.npmjs.com/misc/config>.
+        '';
+        default = ''
+          prefix = ''${HOME}/.npm
+        '';
+        example = ''
+          prefix = ''${HOME}/.npm
+          https-proxy=proxy.example.com
+          init-license=MIT
+          init-author-url=https://www.npmjs.com/
+          color=true
+        '';
+      };
+    };
+  };
+  config = lib.mkIf cfg.enable {
+    home = {
+      packages = lib.mkIf (cfg.package != null) [ cfg.package ];
+      file.".npmrc" = lib.mkIf (cfg.npmrc != "") {
+        text = cfg.npmrc;
+      };
+      sessionVariables = lib.mkIf (cfg.npmrc != "") {
+        NPM_CONFIG_USERCONFIG = "${config.home.homeDirectory}/.npmrc";
+      };
+    };
+  };
+}

tests/modules/programs/npm/default.nix

@@ -0,0 +1,4 @@
+{
+  npm-example-settings = ./example-settings.nix;
+  npm-no-npmrc = ./no-npmrc.nix;
+}

tests/modules/programs/npm/example-settings.nix

@@ -0,0 +1,29 @@
+{ pkgs, ... }:
+
+{
+  programs.npm = {
+    enable = true;
+    npmrc = ''
+      prefix = ''${HOME}/.npm
+      registry=https://registry.example.com/
+      color=true
+    '';
+    package = null;
+  };
+
+  nmt.script =
+    let
+      configPath = "home-files/.npmrc";
+      expectedConfig = pkgs.writeText "npmrc-expected" ''
+        prefix = ''${HOME}/.npm
+        registry=https://registry.example.com/
+        color=true
+      '';
+    in
+    ''
+      assertFileExists "${configPath}"
+      assertFileContent "${configPath}" "${expectedConfig}"
+      assertFileContains home-path/etc/profile.d/hm-session-vars.sh \
+        'export NPM_CONFIG_USERCONFIG="/home/hm-user/.npmrc"'
+    '';
+}

tests/modules/programs/npm/no-npmrc.nix

@@ -0,0 +1,16 @@
+{ pkgs, ... }:
+
+{
+  programs.npm = {
+    enable = true;
+    npmrc = "";
+    package = null;
+  };
+
+  nmt.script = ''
+    assertPathNotExists home-files/.npmrc
+    assertFileExists home-path/etc/profile.d/hm-session-vars.sh
+    assertFileNotRegex home-path/etc/profile.d/hm-session-vars.sh \
+      "export NPM_CONFIG_USERCONFIG="
+  '';
+}